## Numerical solutions and exercises

The xpp file has the following format:

#  hhh.ode
init v=-65  m=0.05  h=0.6  n=0.317
par vna=50  vk=-77  vl=-54.4  gna=120  gk=36  gl=0.3  c=1 phi=1  i0=0
par ip=0 pon=50 poff=150
is(t)=ip*heav(t-pon)*heav(poff-t)
am(v)=phi*.1*(v+40)/(1-exp(-(v+40)/10))
bm(v)=phi*4*exp(-(v+65)/18)
ah(v)=phi*.07*exp(-(v+65)/20)
bh(v)=phi*1/(1+exp(-(v+35)/10))
an(v)=phi*.01*(v+55)/(1-exp(-(v+55)/10))
bn(v)=phi*.125*exp(-(v+65)/80)
v'=(I0+is(t) - gna*h*(v-vna)*m^3-gk*(v-vk)*n^4-gl*(v-vl))/c
m'=am(v)*(1-m)-bm(v)*m
h'=ah(v)*(1-h)-bh(v)*h
n'=an(v)*(1-n)-bn(v)*n
# track the currents
aux ina=gna*(v-vna)*h*m^3
aux ik=gk*(v-vk)*n^4
aux il=gl*(v-vl)
# track the stimulus
aux stim=is(t)
done


Note that I have set to 1 and thus have assumed the standard temperature of I have also kept track of the currents and the stimulus.

We can use this file to explore the dynamics of the HH model as various parameters are changed. The most obvious parameter to vary is the applied current. By setting I0 we can inject a constant current and by setting IP a pulse of current can be injected at PON lasting until POFF. In class I will play around a bit but I want you to do the following experiments. Use the Runge-Kutta integrator with a time-step of 0.05 and set nOut to 10 so that output occurs every half a millisecond. Also set the total amount of time to 200 msec and set the Bounds to 10000 so that the various currents do not exceed them.

1.
With I0=0 try to find the threshold by setting all the variables at rest but incrementing V by different amounts.
2.
Change the current I0 until the neuron fires repetitively. What is the critical value of current that you found?
3.
With I0=10 integrate the equations. In the Data Browser add a column called minf which contains the formula, am(v)/(am(v)+bm(v)). Compare this to the value of m(t) by plotting the two during a few spikes. The two are almost identical. This tells ypu that it may be possible to approximate the dynamics of m by thus making the differential equation one fewer variable.
4.
Next, plot a phase-plane of n and h. They seem to lie along a line. What is the equation for this line? This says that n and h may be linearly related. This means that we may be able to reduce this 4 dimensional system to 2 dimensions by eliminating m and one of n,h.
5.
Set I0=0 and let the membrane start at rest. Set Pon=0, poff=50, ip=-5. This hyperpolarizes the membrane. What happens after the stimulus is removed? You should get a spike. Explain why this happens. (Hint: Look at the variable h during the hyperpolarization. )
6.
Repeat the above experiment but use less negative values of ip is there a critical value below which you get no rebound spike?
7.
Set ip=0, i0=6.5. Solve the equations for v=-61, m=0,h=0.45,n=.4. What happens? Try the same thing with v=-45. What happens? What does this tell you about the number of stable states for the membrane?